Koala Bild + Basic

[Tomas]

Om du inte får till det med TASS kan du prova dreamass ("Dream assembler"). Lika lätt att komma igång med som TASS men också mycket kraftfullare!

Examples:
.binclude "gfx/bitmap01.koa"
This includes the complete file `gfx/bitmap01.koa'.

Jag vet att HCL/Booze Design och Graham/Oxyron har använt denna. Enough said.

Kickassembler är kanske den mest "demovänliga" av dem alla. Enda kruxet är väl att den kräver att du har Java installerat!

[ampli]

är det möjligt att skriva ut text på en bild? eller måste bilden vara en sprite?

/Ampli

[carlsson]

Mja, du kan ju plotta punkter på en högupplöst skärm. Exempel i Basic:

Kod: Markera allt

10 poke53272,24:poke53265,59:print"{clr}"
12 fori=8192to16383:pokei,iand255:next
15 a$="test string":x=10:y=5
16 poke56334,peek(56334)and254:poke1,peek(1)and251
17 fori=1tolen(a$):b=asc(mid$(a$,i,1))and63
18 a=8192+y*320+(x+i)*8
20 forj=0to7:c=peek(53248+b*8+j)
22 pokea+j,c:nextj,i
25 poke1,peek(1)or4:poke56334,peek(56334)or1
30 goto30

Rad 12 behöver du inte om du redan har en högupplöst bild på $2000.
Rad 16 och 25 kopplar in/ut VIC-II så du kan läsa tecken-ROM bakom.
Rad 17 gör om PETSCII till teckenkoder, inte helt perfekt men duger för enkla syften.
Rad 22 ritar ut tecknen. Om du använder pokea+j,peek(a+j)orc så kommer du att väva in texten i grafiken.

Om du arbetar i flerfärgsläge och då vill ha bokstäver med dubbel pixelbredd, blir alltsamman betydligt mer komplicerat. Det lämnas som övning åt läsaren.

[e5frog]

Fyller denna tråd som jag hittade när jag inte hittade informationen jag sökte. Jobbade bara i Advanced Art Studio och Art Studio när jag ritade bilder i min ungdom på C64.

Knåpade ihop detta BASIC-program som visar båda delarna, först högupplöst och sedan multi-color-läge. Går säkert att klura reda på något sätt att identifiera filen från endera filnamnet (PIC för hi MPIC för mult) eller från filens längd eller liknande. Alternativt låta användaren välja.

WinVICE vänlig "copy & paste":

Kod: Markera allt

10 poke53265,43:printchr$(147):n=999:o=55296:p=17208:d=1024:s=16192:q=53280
20 pokeq+1,peek(17193)
30 fori=.ton:poked+i,peek(s+i):pokeo+i,peek(p+i):pokeq,iand3:next
40 pokeq,peek(17193)
50 poke53272,24:poke53265,59:rem bmpmod
60 poke198,0:wait198,1
70 poke53270,peek(53270)or16:rem mulmod
80 poke198,0:wait198,1
90 poke53265,43:?chr$(147):poke53281,6:poke53272,21:poke53270,200:poke53265,27



Kommentarer:
10 släcker skärmen för syns skull, rensar skärm (rev hjärta), variabler laddas för hastighetens skull
20 ställer färg på skärm enligt fildata
30 kopierar färgdata från inladdad fil till dess rätta plats och blinkar skärmen för skojs skull (fördröjer med cirka 4s)
40 ramen samma färg som skärm
50 bitmap-läge - nu visas hi-res
60 invänta knapptryck
70 ställer in multi-läge - nu visas bilden som multi-color
80 vänta på knapptryck
90 återställ till normal skärm för laddning av nästa bild, eller nåt

A.Art Studio har följande format:
$2000-$3F3F bitmap (8000 bytes)
$3F40-$4327 screen RAM (1000 bytes)
$4329 background color (1 byte)
$4338-$471F color RAM (1000 bytes)
För övriga sorter, se här:
http://codebase64.org/doku.php?id=base: ... list_v0.03


Instruktioner:
Ladda BASIC-programmet, ladda in bildfil med LOAD"bild*",8,1 jag är lat själv och skriver bara två eller tre bokstäver av namnet och sedan *. Därefter starta med RUN och titta på blinkande färger i cirka 15 sekunder innan bilden syns i hi-res läge, tryck på tangentbordet för att se den som multi och en gång till för att avsluta.

EDIT:
Om man vill att programmet ska ladda filerna efter att bara a skrivit in namn eller del av namn kan man göra följande tillägg:
Variabeln a behövs för att hoppa över laddningen när programmet startar på nytt/fortsätter efter laddningen genomförts inuti programmet.

Kod: Markera allt

5 ifa=0thena=a+1:input"bildnamn"a$:loada$,8,1
95 run